• kdb+

  Assigning upd inside a function and replay TP log

  Posted by gazi on March 19, 2025 at 2:18 am

  I have created sample tp logs and I want to replay it. However, if the upd function is defined inside a function, the error occurred when I replay. Is it related to scope or namespace? Thanks.

  I’ve simplified my code and put it below.

  Create TP log

  tableName:`students;
  students:([] id:1 2; name:`Foo`Bar);
  
  `:tpLog set ();
  h:hopen`:tpLog;
  {h enlist(`upd;tableName;value x)} each select from tableName;
  hclose h
  \\

  (The code formatting mess up and I can’t fix it. Please ignore those html tags.)

  //Load TP log (with error)
  students:([]id:`long$(); name:`symbol$());
  f:{[x]
    upd:insert;
    -11!`:tpLog
    }["foo"];
  <p><br></p></pre><pre>//Load TP log (without error)
  students:([]id:`long$(); name:`symbol$());
  upd:insert;
  -11!`:tpLog
  

  The error

  'upd
    [3]  /Users/gazi/src/kdb-test/test.q:4: 
    upd:insert;
    -11!`:tpLog
       ^
    }
  

  • This discussion was modified 1 week, 5 days ago by  gazi.
  • This discussion was modified 1 week, 5 days ago by  gazi. Reason: formatting
  • This discussion was modified 1 week, 5 days ago by  gazi. Reason: formatting again
  • This discussion was modified 1 week, 5 days ago by  gazi. Reason: formatting again again
  • This discussion was modified 1 week, 5 days ago by  gazi.

  gazi replied 1 week, 3 days ago 2 Members · 4 Replies
• 4 Replies

• 

  rocuinneagain

  Member

  March 20, 2025 at 10:15 am

  Yes this is a scoping issue. upd in f is a local variable only. You can use set to assign the global variable from within a function.

  students:([]id:`long$(); name:`symbol$());
  f:{[x]
    `upd set insert;
    -11!`:tpLog
    }["foo"];

  • 

    gazi

    Member

    March 20, 2025 at 2:08 pm

    Thanks. I have tried that but the same error occurred.

    • 

      rocuinneagain

      Member

      March 20, 2025 at 2:35 pm

      https://code.kx.com/q/basics/syntax/#prefix-infix-postfix

      Due to insert being a keyword in the language which can operate with infix notation .i.e

      `table insert (1;`Foo)

      The `upd set insert creates a composition rather than executing as you want</p><p><br></p><p>https://code.kx.com/q/ref/compose/#implicit-composition</p><p><br></p><pre>q)`upd set insert
      k){$[@x;.[x;();:;y];-19!((,y),x)]}[`upd]insert<br>q)type[`upd set insert]
      105h

      To bypass this you can use either square or round brackets as follows:

      {[x] set[`upd;insert];-11!`:tpLog}
      {[x] `upd set (insert);-11!`:tpLog}

      :: when executed inside a function can also do global assignment but again needs brackets to execute as you wish:

      https://code.kx.com/q/basics/syntax/#colon-colon

      {[x] upd::(insert);-11!`:tpLog}

      
      

      • This reply was modified 1 week, 4 days ago by  rocuinneagain.
      • This reply was modified 1 week, 4 days ago by  rocuinneagain.

      code.kx.com

      Syntax | Basics | kdb+ and q documentation - kdb+ and q documentation

      Syntax of the q programming language

      • 

        gazi

        Member

        March 21, 2025 at 1:53 am

        I see. Then I need to be careful about that in the future. Thanks for the help.

Log In to Reply